feat: 品牌替换 + 启动优化 + AGENTS.md 模板定制

- 品牌替换：OpenCode/opencode → AirCoding/aircoding（16+ 文件）
- Logo ASCII art：修复 left/right 行数不匹配导致的启动崩溃
- 启动诊断：添加 OPENCODE_PRINT_TIMING 计时探针
- dev 模式默认 --pure 跳过外部插件加载
- AGENTS.md 模板：追加 AirCoding 多 Agent 专项段落
- architect prompt + plugin：强化 AGENTS.md 产出验证

flake.nix

@@ -0,0 +1,73 @@
+{
+  description = "OpenCode development flake";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+  };
+
+  outputs =
+    { self, nixpkgs, ... }:
+    let
+      systems = [
+        "aarch64-linux"
+        "x86_64-linux"
+        "aarch64-darwin"
+        "x86_64-darwin"
+      ];
+      forEachSystem = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
+      rev = self.shortRev or self.dirtyShortRev or "dirty";
+    in
+    {
+      devShells = forEachSystem (pkgs: {
+        default = pkgs.mkShell {
+          packages = with pkgs; [
+            bun
+            nodejs_20
+            pkg-config
+            openssl
+            git
+          ];
+        };
+      });
+
+      overlays = {
+        default =
+          final: _prev:
+          let
+            node_modules = final.callPackage ./nix/node_modules.nix {
+              inherit rev;
+            };
+          in
+          rec {
+            opencode = final.callPackage ./nix/opencode.nix {
+              inherit node_modules;
+            };
+            opencode-desktop = final.callPackage ./nix/desktop.nix {
+              inherit opencode;
+            };
+          };
+      };
+
+      packages = forEachSystem (
+        pkgs:
+        let
+          node_modules = pkgs.callPackage ./nix/node_modules.nix {
+            inherit rev;
+          };
+        in
+        rec {
+          default = opencode;
+          opencode = pkgs.callPackage ./nix/opencode.nix {
+            inherit node_modules;
+          };
+          opencode-desktop = pkgs.callPackage ./nix/desktop.nix {
+            inherit opencode;
+          };
+          # Updater derivation with fakeHash - build fails and reveals correct hash
+          node_modules_updater = node_modules.override {
+            hash = pkgs.lib.fakeHash;
+          };
+        }
+      );
+    };
+}